;;; -*- lexical-binding: t; -*-
;;; Commentary:
;;; Code:


(setopt display-line-numbers-type 'relative)
(defvar bd/enable-line-numbers-in-hooks
  '(prog-mode-hook)
  "List of hook symbols to add `display-line-numbers-mode' to.")
(mapc
 (lambda (hook)
   (add-hook hook #'display-line-numbers-mode))
 bd/enable-line-numbers-in-hooks)

;; skr (skribe) is a scheme extension
(add-to-list 'auto-mode-alist '("\\.skr\\'" . scheme-mode))

(defun bd/beginning-of-visual-line-dwim (&optional n)
  (interactive "P")
  (let ((pt (point)))
    (back-to-indentation)
    (when (or n (eq pt (point)))
      (beginning-of-visual-line n))))

(define-minor-mode dwim-cursor-mode
  "Toggle dwim-cursor-mode."
  :init-value nil
  :group 'quality
  :light " SC"
  :keymap (list
           (cons (kbd "C-a") #'bd/beginning-of-visual-line-dwim)))

(use-package prog-mode
  :hook
  ((js-mode . (lambda ()
                (add-to-list 'prettify-symbols-alist '("function" . ?ƒ))))
   (prog-mode . (lambda ()
                  (font-lock-add-keywords
                   nil '(("\\<\\(FIX\\(ME\\)?\\|TODO\\)"
                          1 font-lock-warning-face t)))))
   (prog-mode . dwim-cursor-mode))
  :config
  (global-prettify-symbols-mode 1))

(use-package tramp
  :config
  (defun request-sudo ()
    "Uses TRAMP to edit current opened file as root."
    (interactive)
    (when buffer-file-name
      (find-alternate-file
       (concat "/sudo:root@localhost:"
               buffer-file-name)))))

(use-package autoformat
  :config
  (setopt autoformat-mode t))

(use-package hl-line
  :hook
  ((prog-mode . hl-line-mode)
   (text-mode . hl-line-mode)))

(use-package compile
  :demand t
  :hook ((compilation-filter . ansi-color-compilation-filter))
  :config
  (setopt compilation-always-kill t
          compilation-scroll-output 'first-error
          compilation-ask-about-save nil)
  (defun bd/compile-dwim (f)
    (let ((default-directory (bd/get-directory-dwim)))
      (call-interactively f)))
  (add-to-list 'display-buffer-alist
               '((major-mode . compilation-mode)
                 (display-buffer-in-side-window)
                 (side . bottom)
                 (slot . -1)
                 (width . 0.15)
                 (post-command-select-window t)))

  (keymap-set prog-mode-map
              "C-," #'(lambda ()
                        (interactive)
                        (bd/compile-dwim #'recompile)))
  (keymap-set prog-mode-map
              "C-<" #'(lambda ()
                        (interactive)
                        (bd/compile-dwim #'compile))))

(use-package man
  :config
  (setopt Man-notify-method 'pushy))

(use-package eldoc
  :init
  (global-eldoc-mode))

(use-package flymake
  :bind (("C-c f f" . #'flymake-mode)
         :map   flymake-mode-map
         ("C-c f s" . #'flymake-start)
         ("C-c f n" . #'flymake-goto-next-error)
         ("C-c f p" . #'flymake-goto-prev-error)
         ("C-c f b" . #'flymake-show-buffer-diagnostics)
         ("C-c f d" . #'flymake-show-project-diagnostics))
  :config
  (setopt flymake-no-changes-timeout nil
          flymake-start-on-flymake-mode t
          flymake-start-on-save-buffer t
          flymake-proc-compilation-prevents-syntax-check t
          flymake-wrap-around nil
          flymake-show-diagnostics-at-end-of-line nil))

(require 'geiser)
(require 'geiser-mode)
(require 'geiser-guile)

(use-package rainbow-mode
  :hook css-mode)

(use-package paren
  :config
  (setopt show-paren-delay 0
          show-paren-highlight-openparen t
          show-paren-context-when-offscreen t
          show-paren-when-point-in-periphery t
          show-paren-when-point-inside-paren t))

(use-package rainbow-delimiters
  :hook prog-mode)

(use-package paredit
  :hook (ielm-mode
         emacs-lisp-mode
         eshell-mode
         geiser-repl-mode
         lisp-mode
         scheme-mode
         lisp-interaction-mode)
  :config
  (defun bd/paredit-preserve-repl (f &rest args)
    "Wrapper around F (paredit-RET), discarding ARGS."
    (pcase (cons major-mode (eolp))
      ('(inferior-emacs-lisp-mode . t) (ielm-return))
      ('(eshell-mode . t) (eshell-send-input))
      ('(geiser-repl-mode . t) (geiser-repl-maybe-send))
      (_ (funcall f))))
  (advice-add #'paredit-RET :around #'bd/paredit-preserve-repl)
  (eldoc-add-command
   'paredit-backward-delete
   'paredit-close-round))


(provide 'bd--devel)
;;; bd--devel.el ends here