tanelorn: Add sent-pdf.

* modules/tanelorn/packages/suckless.scm (sent-pdf): New variable.
* README: Add sent-pdf.

1 files changed, 42 insertions, 0 deletions

diff --git a/modules/tanelorn/packages/suckless.scm b/modules/tanelorn/packages/suckless.scm
new file mode 100644
index 0000000..f2e6047
--- /dev/null
+++ b/modules/tanelorn/packages/suckless.scm
@@ -0,0 +1,42 @@
+;;; Copyright © 2026 bdunahu <bdunahu@operationnull.com>
+;;;
+;;; SPDX-License-Identifier: GPL-3.0-or-later
+
+(define-module (tanelorn packages suckless)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (gnu packages gtk)
+  #:use-module (gnu packages suckless)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix gexp)
+  #:use-module (guix git-download)
+  #:use-module (guix packages)
+  #:use-module (guix utils))
+
+(define-public sent-pdf
+  (let ((commit "0988980aa572f2d1b7b34488d1559e6083a7922f")
+        (revision "1"))
+    (package
+      (inherit sent)
+      (name "sent-pdf")
+      (version (git-version "1" revision commit))
+      (source
+       (origin
+         (method git-fetch)
+         (uri (git-reference
+                (url "https://git.operationnull.com/sent-pdf.git")
+                (commit commit)))
+         (file-name (git-file-name name version))
+         (sha256
+          (base32 "0pm33mg4hj22cpnb2fb7dr3vfv3cd91fjdahdf1lh6435qi3cksq"))))
+      (arguments
+       ;; flags modified to add new cairo input
+       (substitute-keyword-arguments (package-arguments sent)
+         ((#:make-flags _ ''())
+          #~(let ((pkg-config (lambda (flag)
+                                (string-append "$(shell pkg-config " flag " "
+                                               "xft fontconfig x11 libpng cairo)"))))
+              (list (string-append "CC=" #$(cc-for-target))
+                    (string-append "PREFIX=" #$output)
+                    (string-append "INCS=-I. " (pkg-config "--cflags"))
+                    (string-append "LIBS=" (pkg-config "--libs") " -lm"))))))
+      (inputs (modify-inputs (package-inputs sent) (append cairo))))))